@echo off
title fw/wspr decoder
set wavdir1=r:\
set wavdir2=r:\

:loop
timeout 1 >nul
set d1=%date%
set dd=%d1:~0,2%
::set /a dd=dd+100
::set dd=%dd:~1,2%
set yymmdd=%d1:~8,2%%d1:~3,2%%dd%
set t1=%time%
set hh=%t1:~0,2%
set /a hh=hh+100
set hh=%hh:~1,2%
set mm=%t1:~3,2%
set ss=%t1:~6,2%
title %hh%:%mm%:%ss% waiting
if %ss% neq 50 goto loop

set mm30=3%mm%
set /a mm30=mm30%%30+1
set /a mm15=mm30%%15  
set /a mm5=mm30%%5  
set /a mm2=mm30%%2
if %mm5% neq 0 if %mm2% neq 0 goto loop
::if %mm5% neq 0 goto loop

set /a startmin1=100+mm/30*30+100
set startmin1=%startmin1:~1,2%
set fname1=%wavdir2%fwcopy%yymmdd%_%hh%%startmin1%.wav
copy %wavdir1%fw.wav %fname1% /y >nul
if %mm30% equ 30 call :fw 30
if %mm15% equ 0 call :fw 15
if %mm5% equ 0 call :fw 5
if %mm2% equ 0 call :fw 2
del %fname1%
goto loop

:fw
set dur=%1
set /a dursec=dur*60
title %hh%:%mm%:%ss% fw%dur% decode
set /a skipmin=mm30-dur
set /a startmin2=startmin1+skipmin+100
set startmin2=%startmin2:~1,2%
set fname2=%wavdir2%fwcopy%yymmdd%_%hh%%startmin2%.wav
skipwav %fname1% %skipmin% >nul
if not exist %fname2% goto :eof
del decoded.txt >nul
jt9 >nul -W -p %dursec% -f 1500 -F 100 %fname2%
if %fname2% neq %fname1% if %dur% neq 2 del %fname2%
type decoded.txt
::type decoded.txt >>fw%dur%decodedall.txt
type decoded.txt >decoded1.txt
call :setsize decoded1.txt
if %size% equ 0 goto upload
for /f "tokens=1,2,3,4,5,7,8,9" %%i in (decoded1.txt) do @call :dolinef %%i %%j %%k %%l %%m %%n %%o %%p
:upload
call :setsize fw%dur%spots.txt
if %size% equ 0 goto noupload
curl >curllog.txt -s -F allmept=@"fw%dur%spots.txt" -F call="DF6NM" -F grid=JN59nj http://wsprnet.org/meptspots.php
call :setsize curllog.txt
if %size% gtr 40 del fw%dur%spots.txt
:noupload
if %dur% neq 2 goto :eof

:wspr
title %hh%:%mm%:%ss% wspr decode
wsprd >nul -w -f 0.136 %fname2%
if %fname2% neq %fname1% del %fname2%
type wspr_spots.txt >>wsprspots_all.txt
call :setsize wspr_spots.txt
if %size% equ 0 goto upload1
type wspr_spots.txt
type wspr_spots.txt >>wspr_out.txt
for /f "tokens=6,7 delims=<> " %%i in (wspr_spots.txt) do @call :dolinew %%i %%j
:upload1
call :setsize wspr_out.txt
if %size% equ 0 goto :eof
curl >curllog1.txt -s -F allmept=@"wspr_out.txt" -F call="DF6NM" -F grid=JN59nj http://wsprnet.org/meptspots.php
call :setsize curllog1.txt
if %size% gtr 40 del wspr_out.txt
goto :eof

:setsize
set size=0
if exist %1 set size=%~z1
goto :eof

:dolinew
set xcall=x%2
if %xcall% neq %xcall:/=% goto :eof
set f1=%1
set /a f=%f1:~2,6%+4
::start /min /wait msgtest1 n=SpecLab5 m=CL c=EC /sp.print(#0,f=%f%,"%2")
start /min /wait msgtest1 n=SpecLab5 m=CL c=EC /sp.print(#0,fs=14,f=%f%,"%2")
goto :eof

:dolinef
set xcall=x%6
if %xcall% neq %xcall:/=% goto :eof
set f=%5
set f=%f:~0,4%
set /a f=136000+f
set f=0.%f%
set durx=%dur%
if %dur% equ 2 set durx=3
echo %yymmdd% %1 %2 %3 %4 %f% %6 %7 %8 0 %durx% >>fw%dur%spots.txt
echo %yymmdd% %1 %2 %3 %4 %f% %6 %7 %8 0 %durx% >>fw%dur%spotsall.txt
set /a f=%f:~2,6%+2
::start /min /wait msgtest1 n=SpecLab5 m=CL c=EC /sp.print(#0,fc=0xFFFF00,f=%f%,"%6")
start /min /wait msgtest1 n=SpecLab5 m=CL c=EC /sp.print(#0,fs=14,fc=0xFFFF00,f=%f%,"%6")
goto :eof